MLscript demonstration

fun power(x) = case
  0 then `1.0
  n then x `*. power(x)(n - 1)

fun assertNotZero(x) =
  `if (x `== `0.0) then `error else x
let checkedDiv = x `=> y `=> x `/ assertNotZero(y)

fun show: Code[anything, anything] -> Str = _ => "debug"
fun inc(dbg) =
  x `=> let c = x `+ `1 in dbg(c), c
inc(c => log(show(c)))

fun body_naive(x, y) = case
  0 then x
  1 then y
  n then body_naive(y, x `+ y)(n - 1)
fun gib_naive(n) =
  (x, y) `=> body_naive(x, y)(n)
let gn5 = run(gib_naive(5))

fun bind(rhs, k: forall 'g : Code['a, 'g] -> Code['b, 'c | 'g]) =
  `let x = rhs `in k(x)

fun body: forall 'g : (Code[Int, 'g], Code[Int, 'g]) -> Int -> Code[Int, 'g]
fun body(x, y) = case
  0 then x
  1 then y
  n then bind of x `+ y, z => body(y, z)(n - 1)
fun gib(n) = ((x, y) `=> body(x, y)(n))
let g5 = run(gib(5))

mut let qq0 = `0

let foo =
  mut let r = `0
  (x `=> ((set r = x), `0)), r

class Ref[A](init: A) { mut val value: A = init }

let bar = x `=>
  let v = Ref(x)
  let _ = y `=>
    set v.value = y
    `0
  v.value

Note: JavaScript code generation (used to evaluate the result) is not perfect yet and has rough edges. Also, try typing `window.alert of "Hello!"` and see what happens!

MLscript online demonstration

ML_script online demonstration